Flash Image smoothing

Sometime we have to resize JPGs in Flash on a "loadMovie" script by making the target scale - just because. However, this usually makes the image jagged and pixelated - hate it!

So let's fix it. I found this here:

import flash.display.*;

function loadBitmapSmoothed(url:String, target:MovieClip) {
  // Create a movie clip which will contain our
  // unsmoothed bitmap
  var bmc:MovieClip = target.createEmptyMovieClip(
      "bmc",
      target.getNextHighestDepth());

  // Create a listener which will notify us when
  // the bitmap loaded successfully
  var listener:Object = new Object();

  // Track the target
  listener.tmc = target;

  // If the bitmap loaded successfully we redraw the
  // movie into a BitmapData object and then attach
  // that BitmapData to the target movie clip with
  // the smoothing flag turned on.
  listener.onLoadInit = function(mc:MovieClip) {
      mc._visible = false;

      var bitmap:BitmapData = new BitmapData(
          mc._width,
          mc._height,
          true);

       this.tmc.attachBitmap(
          bitmap,
          this.tmc.getNextHighestDepth(),
          "auto",
          true);

       bitmap.draw(mc);
  };

  // Do it, load the bitmap now
  var loader:MovieClipLoader = new MovieClipLoader();
  loader.addListener(listener);
  loader.loadClip(url, bmc);
}


Then all that is left to do is add:

createEmptyMovieClip("myMC",getNextHighestDepth());
loadBitmapSmoothed("mypic.jpg",myMC);